Editing Gauss–Newton algorithm (section)

=== Julia ===
The following implementation in [[Julia (programming language)|Julia]] provides one method which uses a provided Jacobian and another computing with [[automatic differentiation]].<syntaxhighlight lang="julia">
"""
    gaussnewton(r,J,β₀,maxiter,tol)

Perform Gauss-Newton optimization to minimize the residual function `r` with Jacobian `J` starting from `β₀`. The algorithm terminates when the norm of the step is less than `tol` or after `maxiter` iterations.
"""
function gaussnewton(r,J,β₀,maxiter,tol)
    β = copy(β₀)
    for _ in 1:maxiter
        Jβ = J(β);
        Δ  = -(Jβ'*Jβ) \ (Jβ'*r(β)) 
        β += Δ
        if sqrt(sum(abs2,Δ)) < tol
            break
        end
    end
    return β
end

import AbstractDifferentiation as AD, Zygote
backend = AD.ZygoteBackend() # other backends are available

"""
    gaussnewton(r,β₀,maxiter,tol)

Perform Gauss-Newton optimization to minimize the residual function `r` starting from `β₀`. The relevant Jacobian is calculated using automatic differentiation. The algorithm terminates when the norm of the step is less than `tol` or after `maxiter` iterations.
"""
function gaussnewton(r,β₀,maxiter,tol)
    β = copy(β₀)
    for _ in 1:maxiter
        rβ, Jβ = AD.value_and_jacobian(backend,r,β)
        Δ  = -(Jβ[1]'*Jβ[1]) \ (Jβ[1]'*rβ) 
        β += Δ
        if sqrt(sum(abs2,Δ)) < tol
            break
        end
    end
    return β
end
</syntaxhighlight>