Editing Function object (section)

== In Perl ==

In [[Perl]], a function object can be created either from a class's constructor returning a function closed over the object's instance data, blessed into the class:

<syntaxhighlight lang="perl">
package Acc1;
sub new {
    my $class = shift;
    my $arg = shift;
    my $obj = sub {
        my $num = shift;
        $arg += $num;
    };
    bless $obj, $class;
}
1;
</syntaxhighlight>

or by overloading the <code>&{}</code> operator so that the object can be used as a function:

<syntaxhighlight lang="perl">
package Acc2;
use overload
    '&{}' =>
        sub {
            my $self = shift;
            sub {
                my $num = shift;
                $self->{arg} += $num;
            }
        };

sub new {
    my $class = shift;
    my $arg = shift;
    my $obj = { arg => $arg };
    bless $obj, $class;
}
1;
</syntaxhighlight>

In both cases the function object can be used either using the dereferencing arrow syntax ''$ref->(@arguments)'':

<syntaxhighlight lang="perl">
use Acc1;
my $a = Acc1->new(42);
print $a->(10), "\n";    # prints 52
print $a->(8), "\n";     # prints 60
</syntaxhighlight>
or using the coderef dereferencing syntax ''&$ref(@arguments)'':
<syntaxhighlight lang="perl">
use Acc2;
my $a = Acc2->new(12);
print &$a(10), "\n";     # prints 22
print &$a(8), "\n";      # prints 30
</syntaxhighlight>