Editing Common Lisp (section)

===Sorting a list of person objects===

We define a class <code>person</code> and a method for displaying the name and age of a person.
Next we define a group of persons as a list of <code>person</code> objects.
Then we iterate over the sorted list.

<syntaxhighlight lang="lisp">
(defclass person ()
  ((name :initarg :name :accessor person-name)
   (age  :initarg :age  :accessor person-age))
  (:documentation "The class PERSON with slots NAME and AGE."))

(defmethod display ((object person) stream)
  "Displaying a PERSON object to an output stream."
  (with-slots (name age) object
    (format stream "~a (~a)" name age)))

(defparameter *group*
  (list (make-instance 'person :name "Bob"   :age 33)
        (make-instance 'person :name "Chris" :age 16)
        (make-instance 'person :name "Ash"   :age 23))
  "A list of PERSON objects.")

(dolist (person (sort (copy-list *group*)
                      #'>
                      :key #'person-age))
  (display person *standard-output*)
  (terpri))
</syntaxhighlight>

It prints the three names with descending age.
<syntaxhighlight lang="text">
Bob (33)
Ash (23)
Chris (16)
</syntaxhighlight>