Editing Backus–Naur form (section)

==BNF representation of itself==

[[File:Bnf-syntax-diagram.png|thumb|alt=BNF syntax diagram |BNF [[syntax diagram]]]]

BNF's syntax itself may be represented with a BNF like the following:
<syntaxhighlight lang="bnf">
 <syntax>         ::= <rule> | <rule> <syntax>
 <rule>           ::= <opt-whitespace> "<" <rule-name> ">" <opt-whitespace> "::=" <opt-whitespace> <expression> <line-end>
 <opt-whitespace> ::= " " <opt-whitespace> | ""
 <expression>     ::= <list> | <list> <opt-whitespace> "|" <opt-whitespace> <expression>
 <line-end>       ::= <opt-whitespace> <EOL> | <line-end> <line-end>
 <list>           ::= <term> | <term> <opt-whitespace> <list>
 <term>           ::= <literal> | "<" <rule-name> ">"
 <literal>        ::= '"' <text1> '"' | "'" <text2> "'"
 <text1>          ::= "" | <character1> <text1>
 <text2>          ::= "" | <character2> <text2>
 <character>      ::= <letter> | <digit> | <symbol>
 <letter>         ::= "A" | "B" | "C" | "D" | "E" | "F" | "G" | "H" | "I" | "J" | "K" | "L" | "M" | "N" | "O" | "P" | "Q" | "R" | "S" | "T" | "U" | "V" | "W" | "X" | "Y" | "Z" | "a" | "b" | "c" | "d" | "e" | "f" | "g" | "h" | "i" | "j" | "k" | "l" | "m" | "n" | "o" | "p" | "q" | "r" | "s" | "t" | "u" | "v" | "w" | "x" | "y" | "z"
 <digit>          ::= "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"
 <symbol>         ::= "|" | " " | "!" | "#" | "$" | "%" | "&" | "(" | ")" | "*" | "+" | "," | "-" | "." | "/" | ":" | ";" | ">" | "=" | "<" | "?" | "@" | "[" | "\" | "]" | "^" | "_" | "`" | "{" | "}" | "~"
 <character1>     ::= <character> | "'"
 <character2>     ::= <character> | '"'
 <rule-name>      ::= <letter> | <rule-name> <rule-char>
 <rule-char>      ::= <letter> | <digit> | "-"
</syntaxhighlight>

Note that "" is the [[empty string]].

The original BNF did not use quotes as shown in <code>&lt;literal&gt;</code> rule. This assumes that no [[whitespace (computer science)|whitespace]] is necessary for proper interpretation of the rule.

<code>&lt;EOL&gt;</code> represents the appropriate [[newline|line-end]] specifier (in [[ASCII]], carriage-return, line-feed or both depending on the [[operating system]]). <code>&lt;rule-name&gt;</code> and <code>&lt;text&gt;</code> are to be substituted with a declared rule's name/label or literal text, respectively.

In the U.S. postal address example above, the entire block-quote is a <code>&lt;syntax&gt;</code>.  Each line or unbroken grouping of lines is a rule; for example one rule begins with <code>&lt;name-part&gt; ::=</code>. The other part of that rule (aside from a line-end) is an expression, which consists of two lists separated by a vertical bar <code>|</code>.  These two lists consists of some terms (three terms and two terms, respectively).  Each term in this particular rule is a rule-name.